如需查看完整的文档索引,请参阅 llms.txt。在文档页面的 URL 末尾加上 .md 即可查看该页面的 Markdown 版本。
主导航
主题

导入 OpenAI 资源并处理配置漂移

将现有资源纳入 Terraform 管理并检测配置漂移。

您可以直接导入现有 OpenAI 资源,无需重新创建。要安全地将资源纳入 Terraform 管理,请先编写与远程资源当前设置一致的配置,再预览并应用导入计划。在进行任何预定的更新之前,重新生成计划并确认没有变更。

导入块要求使用 Terraform 1.5 或更高版本。

声明并导入资源

按每个现有资源的当前设置声明该资源,然后添加 import 块,并使用提供程序参考文档中指定的 ID 格式:

resource "openai_project" "existing" {
  name = "existing-project"
}

resource "openai_group" "existing" {
  name = "existing-group"
}

resource "openai_project_service_account" "existing" {
  project_id = openai_project.existing.project_id
  name       = "existing-service-account"
}

import {
  to = openai_project.existing
  id = "proj_123"
}

import {
  to = openai_group.existing
  id = "group_123"
}

import {
  to = openai_project_service_account.existing
  id = "proj_123/svc_acct_123"
}

生成并保存计划,然后查看计划中的导入操作:

terraform plan -out=tfplan
terraform show tfplan

计划应列出导入操作,且不应包含对远程资源的更新。如果计划包含更新,请先调整配置,使其与资源的当前设置一致,再继续操作。应用已保存的计划以执行导入,然后重新生成计划:

terraform apply tfplan
terraform plan

第二次生成的计划应显示没有变更。您可以在配置中保留导入块,记录 Terraform 如何将这些资源纳入管理。

常见的导入 ID 格式如下:

资源 导入 ID 格式
项目 <project_id>
组织群组 <group_id>
项目角色 <project_id>/<role_id>
项目服务账号 <project_id>/<service_account_id>
项目群组角色 <project_id>/<group_id>/<role_id>
项目用户角色 <project_id>/<user_id>/<role_id>
项目速率限制 <project_id>/<rate_limit_id>

有关各类资源的确切导入 ID 格式,请查阅提供程序参考文档。

读取由其他系统管理的资源

如果 Terraform 需要获取资源的最新信息,而该资源由其他系统管理,请使用数据源。提供程序为项目、群组、角色、用户、角色分配、速率限制、模型权限、托管工具权限、支出提醒、数据保留和证书提供了数据源。

例如,您可以读取现有项目及其当前的群组:

data "openai_project" "existing" {
  project_id = var.project_id
}

data "openai_project_groups" "existing" {
  project_id = data.openai_project.existing.project_id
}

output "project_groups" {
  value = data.openai_project_groups.existing.groups
}

提供程序支持按 ID 导入现有项目服务账号,但目前尚未提供服务账号数据源。如果您需要将现有服务账号纳入 Terraform 管理,请在经批准的资源清单中保留项目 ID 和服务账号 ID。有关初始化 API 密钥和导入服务账号的操作顺序,请参阅服务账号。

检测并处理配置漂移

按常规方式生成计划,让 Terraform 读取当前的 OpenAI 设置,并将其与 Terraform 配置中的期望值进行比较:

terraform plan -detailed-exitcode

退出码 0 表示没有变更,2 表示计划包含变更,1 表示 Terraform 遇到了错误。

如果计划显示某项设置在 Terraform 之外发生了更改:

  1. 确认这项更改是否有意为之。
  2. 如果要保留远程更改,请更新 Terraform 配置,使其与远程设置一致。
  3. 如果要撤销远程更改,请检查并应用计划,将该设置恢复为配置中指定的值。
  4. 重新生成计划,并确认结果显示没有变更。

了解移除资源的影响

移除资源块并应用变更后,Terraform 会从状态中移除相应资源。对远程对象的影响取决于资源类型:

资源类型 移除后的行为
openai_project 归档项目。项目一旦归档便无法恢复。
openai_project_service_account 删除服务账号。
角色、群组、成员关系和分配资源 删除相应的受管对象或分配关系。
openai_project_model_permissions 删除项目的模型权限配置。
项目速率限制、托管工具权限和数据保留资源 从 Terraform 状态中移除资源,保留当前远程设置。